Track how you're going with your follower goals.
Follower Goals
Platforms
Formulas Used
Increase
if(empty(prop("Initial")) or empty(prop("Current")), toNumber(""), prop("Current") - prop("Initial"))
Remaining
if(prop("Goal") - prop("Current") > 0, prop("Goal") - prop("Current"), 0)
Required per Day
ceil((prop("Goal") - prop("Current")) / dateBetween(prop("Deadline"), now(), "days"))
Days to Succeed
dateBetween(prop("Completed"), if(empty(prop("Goal Started")), prop("Account Started"), prop("Goal Started")), "days")
Average per Day
if(empty(prop("Completed")), toNumber(""), if(prop("Current") >= prop("Goal"), round(prop("Increase") / dateBetween(prop("Completed"), if(empty(prop("Goal Started")), prop("Account Started"), prop("Goal Started")), "days")), toNumber("")))
Platform & Deadline
if(empty(prop("Platform")) or empty(prop("Goal")), "", if(prop("Platform") == "Twitter", "🐤 ", if(prop("Platform") == "Instagram", "📷 ", if(prop("Platform") == "Reddit", "👽 ", if(prop("Platform") == "Facebook", "😀 ", if(prop("Platform") == "LinkedIn", "🔗 ", ""))))) + format(prop("Goal")) + if(empty(prop("Platform")), " followers", " on " + prop("Platform")) + " • 🏁 " + if(prop("Current") / prop("Goal") >= 1, "Completed " + format(prop("Completed")), format(if(empty(prop("Goal Started")), prop("Account Started"), prop("Goal Started"))) + " → " + format(prop("Deadline"))))
Remaining & Per Day
if(empty(prop("Platform")), "", if(not empty(prop("Completed")) and prop("Current") / prop("Goal") >= 1, "🗓 You did it in " + format(prop("Days to Succeed")) + " days, averaging " + format(prop("Avg. per Day")) + " followers a day!", "🧮 " + format(prop("Current")) + " / " + format(prop("Goal")) + " • " + "🗓 " + format(prop("Remaining")) + " to go: that's " + format(prop("Req. per Day")) + " per day!"))
Progress
if(empty(prop("Platform")), "", if(prop("Current") / prop("Goal") >= 1, "🎉 ●●●●●●●●●● 100% baby!", "⏳ " + format(slice("●●●●●●●●●●", 0, floor(prop("Current") / prop("Goal") * 10)) + format(slice("○○○○○○○○○○", 0, ceil(10 - prop("Current") / prop("Goal") * 10)) + " " + format(round(prop("Current") / prop("Goal") * 1000) / 10) + "%"))))
