クオータの初日を得るには?

月ではなくクオータで仕事を管理している人もいろようです。そこで、日付からクオータの初日を取り出してみます。Formula 2.0 から月は 1 から 12 になりましたので、-1 が追加されています。

「月初日」を使う場合


lets(
 /* 月初日プロパティの値を変数 d に代入 */
 d, prop("月初日"),
 /* 月を示す数値から1を引いたもの(0-11)の3の剰余を計算し変数 msub に代入(0-2) */
 msub, (d.month() - 1) % 3,
  /* d から msub 月前の日付を計算 (1月, 4月, 7月, 10月のいずれか) */
  d.dateSubtract(msub, "months")
)

→

「時刻なし」を使う場合


lets(
 /* 時刻なしプロパティの値を変数 d に代入 */
 d, prop("時刻なし"),
 /* d の日付数値から1を引いた数値を dsub に代入 */
 dsub, d.date() - 1,
 /* 月を示す数値から1を引いたもの(0-11)の3の剰余を計算し変数 msub に代入(0-2) */
 msub, (d.month() - 1) % 3,
  /* d から dsub 日前の日付を計算 (今月1日) */
  d.dateSubtract(dsub, "days")
   /* その日付から msub 月前の日付を計算 (1月, 4月, 7月, 10月のいずれか) */
   .dateSubtract(msub, "months")
)

→

参照なし。こちらも Formula 2.0 から導入された parseDate を使います。


lets(
 /* 日付プロパティの日付から時刻情報を削り、変数 d に代入 */
 d, prop("日付").formatDate("YYYY-MM-DD").parseDate(),
 /* d の日付数値から1を引いた数値を dsub に代入 */
 dsub, d.date() - 1,
 /* 月を示す数値から1を引いたもの(0-11)の3の剰余を計算し変数 msub に代入(0-2) */
 msub, (d.month() - 1) % 3,
  /* d から dsub 日前の日付を計算 (今月1日) */
  d.dateSubtract(dsub, "days")
   /* その日付から msub 月前の日付を計算 (1月, 4月, 7月, 10月のいずれか) */
   .dateSubtract(msub, "months")
)

→